opamp_sando's blog

クソザコが割りと適当なことを書くためにある備忘録です。あとたまに普通の日記も書きます

tcshに戻ってみた

長いことzshを使ってきたけど、今日出かけた本屋でみたkshの本を思い出してそういえばzshって起動すごい遅いことを再度考えた。頻繁にterminalつけたり切ったりするおいらとしては割りと辛いことで。
もしかしたら改善策があるのかもしれないが、前に使ってたtcshに戻ってみることにした。
で、しばらく使って何か不都合が起こって解決できなかったらzshに戻ろうかなーと。

で、今回は気合を入れて.tcshrcを1から書いてみた。下手な英語付きで。

#-- opamp's tcsh setting ---------------------------------------------------+
# If you want to change path,you should change ~/.tcsh/*.path files.        |
# And,you should change ~/.tcsh/*.alias if you want to add or delete alias. |
#                                                                           |
# This .tcshrc distinguish your platform,Darwin,Linux and FreeBSD.          |
# You can set each setting to ~/.tcsh/platform.*                            |
#                                                                           |
# I prefer vi to default.therefore,my tcsh is binded vi-like.           |
#---------------------------------------------------------------------------+

#setenv LANG
set color
bindkey -v #vi key bind

#common paths
setenv PATH /bin:/usr/bin:/usr/local/bin:/sbin:/usr/sbin:/usr/local/sbin

#common alias
source $HOME/.tcsh/common.alias

set UNAME=`uname`
#OS JUNCTION
if($UNAME == "Darwin") then #When OSX(Darwin)
#For Prompt---------------------------------
	set prompt='[%{\e[33m%d\e[00m%} %{\e[31m%W/%D/%Y\e[00m%}:%{\e[31m%T\e[00m%}](%{\e[30;41m%~\e[00m%})\
%{\e[01m[Darwin]%n\e[00m%} >'
#-------------------------------------------
	source $HOME/.tcsh/mac.alias
	source $HOME/.tcsh/mac.path	


else if($UNAME == "Linux") then #When Linux(Maybe ArchLinux :-)
#For Prompt---------------------------------
	set prompt='[%{\e[33m%d\e[00m%} %{\e[32m%W/%D/%Y\e[00m%}:%{\e[32m%T\e[00m%}](%{\e[30;41m%~\e[00m%})\
%{\e[01m[Linux]%n\e[00m%} >'
#-------------------------------------------
	source $HOME/.tcsh/linux.alias


else if($UNAME == "FreeBSD") then #When FreeBSD
#For Prompt---------------------------------
	set prompt='[%{\e[33m%d\e[00m%} %{\e[36m%W/%D/%Y\e[00m%}:%{\e[36m%T\e[00m%}](%{\e[30;41m%~\e[00m%})\
%{\e[01m[FreeBSD]%n\e[00m%} >'
#-------------------------------------------
	source $HOME/.tcsh/freebsd.alias

else 
#For Prompt---------------------------------
	set prompt='[%{\e[33m%d\e[00m%} %{\e[34m%W/%D/%Y\e[00m%}:%{\e[34m%T\e[00m%}](%{\e[30;41m%~\e[00m%})\
%{\e[01m[Unknown]%n\e[00m%} >'
#-------------------------------------------

endif

if(-e $HOME/.tcshrc.mine && -r $HOME/.tcshrc.mine) then
	source $HOME/.tcshrc.mine
endif

setenv PAGER "less"
setenv EDITOR "vim"
#disable coredump
limit coredumpsize 0

#history
set history=150
set savehist=(1000 merge)

#autolist
set autolist

# exclude complement
set fignore=(.log)

# notify
#set notify

# confirm rmstart
set rmstar

# autocorrect
set autocorrect

# correct commands
set correct=cmd

ま、ちょっとzshtcshもさほど詳しくないのでググって出た程度の情報で頑張って書いてこの程度が限界だった。
$HOME/.tcsh以下にmac.aliasとかmac.pathとかlinux.aliasとか使っていろんなOS向けの設定を違うファイルに書くようにした。それを読み込む設定。
もし自分専用設定があるなら~/.tcshrc.mineに書き込んでおけばロードしてくれる。

まあ、今後も色々改良してみようかな。ちなみにバックアップがてらgistにもあげてる。
しかしtcshはif文使いやすくていいね。

Firefox ブラウザ無料ダウンロード